Conformal Block Expansion of the Free Scalar Four-Point Function

Definitions

(*The free scalar four-point function*)

𝒢[z_,zb_]:=(1/(z zb))+1+(1/((1-z)(1-zb)));

(*The conformal blocks for identical scalars in 4d CFT.*)

conformalBlock[ΔO_][Δ_,J_][z_,zb_]:=(((z zb))^(-ΔO))((z zb)/(zb-z))(k[((Δ-J-2)/2)][z]k[((Δ+J)/2)][zb]-k[((Δ-J-2)/2)][zb]k[((Δ+J)/2)][z]);

k[h_][z_]:=(z^h)Hypergeometric2F1[h,h,2h,z];

Checks

(*Identity exchange*)

conformalBlock[1][0,0][z,zb]//Simplify

(*The first few coefficients*)

Series[𝒢[z,zb]-((1/(z zb))+2conformalBlock[1][2,0][z,zb]+(1/3)conformalBlock[1][4,2][z,zb]+(1/35)conformalBlock[1][6,4][z,zb])/.{z->r (E^(I θ)),zb->r (E^(-I θ))},{r,0,4}]//FullSimplify

ClearAll[cSquared]

(*Exact formula for ((Subscript[c, ϕϕm])^2)*)

cSquared[J_]:=((2(((J!))^2))/((2J)!));

(*Checking the OPE/conformal block decomposition order by order around z=zb=0*)

Module[{JMax=40},
Series[𝒢[z,zb]-((1/(z zb))+Sum[cSquared[J]conformalBlock[1][J+2,J][z,zb],{J,0,JMax,2}])/.{z->r (E^(I θ)),zb->r (E^(-I θ))},{r,0,JMax}]//FullSimplify
]

(*Checking the OPE/conformal block decomposition at finite z,zb.*)

Module[{JMax=40,r=SetPrecision[(1/3),50],θ=SetPrecision[π/10,50]},
((𝒢[z,zb])/((1/(z zb))+Sum[cSquared[J]conformalBlock[1][J+2,J][z,zb],{J,0,JMax,2}]))/.{z->r (E^(I θ)),zb->r (E^(-I θ))}
]